lionel.b.dyck@kp.org (Lionel B. Dyck):

This 'tip' is for those using the new lite version of PC/3270 that comes
with Merlin but are still used to typing TN3270 or PMANT.  This is a 
rexx exec that invokes PC/3270 for those who haven't retrained their
fingers.  It isn't a complete 'clone' of tn3270/pmant but it does the
job and it is free (with no guarantees).

/* rexx simulation of TN3270/PMANT to activate PC/3270 'lite'
   using the TN3270/PMANT command prompt.

   Syntax:  tn3270 host options
         or pmant  host options

   This command should be installed as both tn3270.cmd AND pmant.cmd
   to allow you to use either command name.

   Supported Options are:
            rows - number of rows per screen
            cols - number of columns per screen

   Note:  The rows and columns must conform to a valid combination
          or pc/3270 will default to 24x80.  Supported combinations
          appear to be 24x80, 32x80, 43x80, and 27x132.

   Logic:   1.  Parse input options
            2.  Prompt for host name if non provided
            3.  Check for rows and columns
            4.  Build temp pc/3270 .ws file in tmp directory
            5.  Invoke pcsws (pc/3270 lite) passing the .ws file
                name (3)
            6.  Delete the temp .ws file (4) and exit

   Author:  Lionel B. Dyck
            Kaiser Foundation Health Plan
            25 N. Via Monte Ave
            Walnut Creek, CA 94598
            (510) 926-5332
            Internet: lionel.b.dyck@kp.org

*/

arg host_name options

do while length(host_name) = 0
   say "Enter host name:"
   pull host_name
   end

/* set defaults */
screen_rows = 24
screen_cols = 80

options = translate(options)

parse value options with 1 'ROWS' rows . 1 'COLS' cols .

if length(rows) > 0 then screen_rows = rows
if length(cols) > 0 then screen_cols = cols

Call RxFuncAdd 'SysLoadFuncs','RexxUtil','SysLoadFuncs'
Call SysLoadFuncs

tmp = value("TMP",,"OS2ENVIRONMENT")

parse value time() with hh ":" mm ":" ss

file = tmp"\"hh""mm""ss".ws"

call lineout file,"[Profile]"
call lineout file,"ID=WS"
call lineout file,"Description="
call lineout file,""
call lineout file,"[Translation]"
call lineout file,"IBMDefaultView=Y"
call lineout file,"DefaultView="
call lineout file,"IBMDefaultDBCS=Y"
call lineout file,"DefaultDBCS="
call lineout file,""
call lineout file,"[Communication]"
call lineout file,"AutoConnect=Y"
call lineout file,"Link=telnet3270"
call lineout file,"Session=3270"
call lineout file,""
call lineout file,"[Telnet3270]"
call lineout file,"HostName="host_name
call lineout file,"HostPortNumber=23"
call lineout file,"LUName="
call lineout file,"AutoReconnect=Y"
call lineout file,"ExtendedColor=Y"
call lineout file,"ATTN=6CFFEFFFF3"
call lineout file,"SYSREQ=F0FFEF"
call lineout file,""
call lineout file,"[3270]"
call lineout file,"ScreenSize="screen_rows"x"screen_cols
call lineout file,"SessionType=Display"
call lineout file,"HostGraphics=N"
call lineout file,"NativeGraphics=N"
call lineout file,"LoadPSS=N"
call lineout file,"QueryReplyMode=Auto"
call lineout file,"HostCodePage=037-U"
call lineout file,"LtNumber=FF"
call lineout file,"LuNumber=FF"
call lineout file

"@pcsws" file

"@del" file

Exit

file,:
  arg data
  line = out.0 + 1
  out.line = data
  out.0 = line
  return